{
  lib,
  config,
  ...
}: let
  stateDir = "/var/lib/forgejo";
in {
  options.services.forgejo.impermanence.enable = lib.mkOption {
    type = lib.types.bool;
    default = config.services.forgejo.enable && config.storage.impermanence.enable;
  };

  config = lib.mkIf config.services.forgejo.enable (lib.mkMerge [
    (lib.mkIf config.storage.zfs.enable (lib.mkMerge [
      {
        assertions = [
          {
            assertion = config.services.forgejo.stateDir == stateDir;
            message = "forgejo state directory does not match persistence";
          }
        ];
      }
      (lib.mkIf (!config.services.forgejo.impermanence.enable) {
        # TODO: placeholder to configure a unique dataset for this service
      })
      (lib.mkIf config.services.forgejo.impermanence.enable {
        storage.impermanence.datasets."persist/replicate/system/root" = {
          directories."${stateDir}" = {
            owner.name = "forgejo";
            group.name = "forgejo";
          };
        };
      })
    ]))
  ]);
}