{
  lib,
  config,
  ...
}: let
  const = import ./const.nix;
  dataDirectory = const.dataDirectory;
in {
  options.services.actual.impermanence.enable = lib.mkOption {
    type = lib.types.bool;
    default = config.services.actual.enable && config.storage.impermanence.enable;
  };

  config = lib.mkIf config.services.actual.enable (lib.mkMerge [
    (lib.mkIf config.storage.zfs.enable (lib.mkMerge [
      {
        assertions = [
          {
            assertion = config.services.actual.settings.dataDir == dataDirectory;
            message = "actual data location does not match persistence\nconfig directory: ${config.services.actual.settings.dataDir}\npersistence directory: ${dataDirectory}";
          }
          {
            assertion = config.systemd.services.actual.serviceConfig.DynamicUser or false;
            message = "actual systemd service must have DynamicUser enabled to use private directory";
          }
        ];
      }
      (lib.mkIf (!config.services.actual.impermanence.enable) {
        # TODO: placeholder to configure a unique dataset for this service
      })
      (lib.mkIf config.services.actual.impermanence.enable {
        storage.impermanence.datasets."persist/replicate/system/root" = {
          directories."${dataDirectory}" = {
            owner.name = "actual";
            group.name = "actual";
          };
        };
      })
    ]))
  ]);
}