{
  lib,
  config,
  ...
}: let
  const = import ./const.nix;
  dataDirectory = const.dataDirectory;
in {
  options.services.actual = {
    impermanence.enable = lib.mkOption {
      type = lib.types.bool;
      default = config.services.actual.enable && config.host.impermanence.enable;
    };
  };

  config = lib.mkIf config.services.actual.impermanence.enable {
    assertions = [
      {
        assertion = config.services.actual.settings.dataDir == dataDirectory;
        message = "actual data location does not match persistence\nconfig directory: ${config.services.actual.settings.dataDir}\npersistence directory: ${dataDirectory}";
      }
      {
        assertion = config.systemd.services.actual.serviceConfig.DynamicUser or false;
        message = "actual systemd service must have DynamicUser enabled to use private directory";
      }
    ];
    environment.persistence."/persist/system/root" = {
      directories = [
        {
          directory = dataDirectory;
          user = "actual";
          group = "actual";
        }
      ];
    };
  };
}