{
  config,
  lib,
  ...
}: let
  dataDir = "/var/lib/paperless";
in {
  options.services.paperless.impermanence.enable = lib.mkOption {
    type = lib.types.bool;
    default = config.services.paperless.enable && config.storage.impermanence.enable;
  };

  config = lib.mkIf config.services.paperless.enable (lib.mkMerge [
    (lib.mkIf config.storage.zfs.enable (lib.mkMerge [
      {
        assertions = [
          {
            assertion = config.services.paperless.dataDir == dataDir;
            message = "paperless data location does not match persistence";
          }
        ];
      }
      (lib.mkIf (!config.services.paperless.impermanence.enable) {
        # TODO: placeholder to configure a unique dataset for this service
      })
      (lib.mkIf config.services.paperless.impermanence.enable {
        storage.impermanence.datasets."persist/replicate/system/root" = {
          directories."${dataDir}" = {
            owner.name = "paperless";
            group.name = "paperless";
          };
        };
      })
    ]))
  ]);
}