refactor: made pkgs dendrites

modules/nixos/pkgs/mapillary-uploader.nix

@@ -0,0 +1,49 @@
+{...}: let
+  package = {
+    lib,
+    fetchurl,
+    appimageTools,
+  }: let
+    pname = "mapillary-uploader";
+    version = "4.7.2";
+
+    src = fetchurl {
+      url = "http://tools.mapillary.com/uploader/download/linux/${version}";
+      name = "mapillary-uploader.AppImage";
+      sha256 = "sha256-hpWdfeuhYylO+SFD3BsKI0s/xtObCDd5OcuJ6i/aEuI=";
+    };
+
+    appimageContents = appimageTools.extractType2 {
+      inherit pname version src;
+    };
+  in
+    appimageTools.wrapType2 {
+      inherit pname version src;
+
+      extraInstallCommands = ''
+        # Install desktop file
+        install -Dm644 ${appimageContents}/mapillary-desktop-uploader.desktop $out/share/applications/mapillary-uploader.desktop
+
+        # Fix desktop file paths
+        substituteInPlace $out/share/applications/mapillary-uploader.desktop \
+          --replace 'Exec=AppRun' 'Exec=${pname}'
+      '';
+
+      meta = with lib; {
+        description = "Mapillary Desktop Uploader - Upload street-level imagery to Mapillary";
+        homepage = "https://www.mapillary.com/";
+        license = licenses.unfree; # Mapillary's license terms
+        maintainers = [];
+        platforms = ["x86_64-linux"];
+        sourceProvenance = with sourceTypes; [binaryNativeCode];
+      };
+    };
+in {
+  flake.commonModules.mapillary-uploader = {pkgs, ...}: {
+    nixpkgs.overlays = [
+      (final: prev: {
+        mapillary-uploader = pkgs.callPackage package {};
+      })
+    ];
+  };
+}