refactor: made pkgs dendrites

modules/nixos/pkgs/h3-c-lib.nix

@@ -0,0 +1,47 @@
+{...}: let
+  package = {
+    lib,
+    stdenv,
+    fetchFromGitHub,
+    cmake,
+    doxygen,
+  }:
+    stdenv.mkDerivation rec {
+      pname = "h3";
+      version = "4.3.0";
+
+      src = fetchFromGitHub {
+        owner = "uber";
+        repo = "h3";
+        rev = "v${version}";
+        hash = "sha256-DUILKZ1QvML6qg+WdOxir6zRsgTvk+En6yjeFf6MQBg=";
+      };
+
+      nativeBuildInputs = [
+        cmake
+        doxygen
+      ];
+
+      cmakeFlags = [
+        "-DBUILD_SHARED_LIBS=ON"
+        "-DBUILD_TESTING=OFF"
+      ];
+
+      meta = with lib; {
+        homepage = "https://github.com/uber/h3";
+        description = "Hexagonal hierarchical geospatial indexing system";
+        license = licenses.asl20;
+        maintainers = [];
+        platforms = platforms.all;
+      };
+    };
+in {
+  flake.commonModules.h3-c-lib = {pkgs, ...}: {
+    nixpkgs.overlays = [
+      (final: prev: {
+        # Override h3 C library to version 4.3.0
+        h3 = pkgs.callPackage package {};
+      })
+    ];
+  };
+}