refactor: made pkgs dendrites

2026-04-07 08:45:11 -05:00 · 2026-04-07 08:45:11 -05:00 · df8dd110ad
commit df8dd110ad
parent 88041e86bd
54 changed files with 1184 additions and 1058 deletions
--- a/modules/nixos/pkgs/gdx-liftoff.nix
+++ b/modules/nixos/pkgs/gdx-liftoff.nix
@ -0,0 +1,58 @@
+{...}: let
+  package = {
+    stdenv,
+    fetchurl,
+    makeWrapper,
+    jdk,
+    lib,
+    libGL,
+    libx11,
+    libxcursor,
+    libxext,
+    libxrandr,
+    libxxf86vm,
+    ...
+  }:
+    stdenv.mkDerivation rec {
+      pname = "gdx-liftoff";
+      version = "1.13.5.1";
+
+      src = fetchurl {
+        url = "https://github.com/libgdx/gdx-liftoff/releases/download/v${version}/gdx-liftoff-${version}.jar";
+        hash = "sha256-9vCXGNGwI/P4VmcdIzTv2GPAX8bZb7nkfopaRAf6yMA=";
+      };
+
+      dontUnpack = true;
+
+      nativeBuildInputs = [makeWrapper];
+
+      runtimeDependencies = lib.makeLibraryPath [
+        # glfw
+        libGL
+        libx11
+        libxcursor
+        libxext
+        libxrandr
+        libxxf86vm
+      ];
+
+      installPhase = ''
+        runHook preInstall
+
+        install -Dm644 $src $out/lib/gdx-liftoff-${version}.jar
+
+        makeWrapper ${lib.getExe jdk} $out/bin/gdx-liftoff-${version} \
+          --append-flags "-jar $out/lib/gdx-liftoff-${version}.jar"\
+          ${lib.optionalString stdenv.hostPlatform.isLinux "--prefix LD_LIBRARY_PATH : ${runtimeDependencies}"}
+        runHook postInstall
+      '';
+    };
+in {
+  flake.commonModules.gdx-liftoff = {pkgs, ...}: {
+    nixpkgs.overlays = [
+      (final: prev: {
+        gdx-liftoff = pkgs.callPackage package {};
+      })
+    ];
+  };
+}