refactor: made pkgs dendrites

modules/nixos/pkgs/codium-extensions/ai-code.nix

@@ -0,0 +1,46 @@
+{...}: let
+  package = {
+    buildNpmPackage,
+    vscode-utils,
+    pkgs,
+    ...
+  }: let
+    version = "0.0.1";
+    pname = "ai-code";
+    publisher = "jan-leila";
+    vsix = buildNpmPackage {
+      inherit version pname;
+
+      src = builtins.fetchGit {
+        url = "ssh://git@git.jan-leila.com/jan-leila/ai-code.git";
+        rev = "d48e01713021dbb30de0ebbee2cfaf99e4e9b5a6";
+      };
+
+      npmDepsHash = "sha256-kjMyEnT3dz0yH5Ydh+aGoFDocKpBYGRmfnwbEdvvgpY=";
+
+      nativeBuildInputs = with pkgs; [
+        vsce
+      ];
+
+      buildPhase = ''
+        ${pkgs.vsce}/bin/vsce package -o ${pname}.zip
+      '';
+
+      installPhase = ''
+        mkdir -p $out
+        mv ${pname}.zip $out/${pname}.zip
+      '';
+    };
+  in
+    vscode-utils.buildVscodeExtension {
+      inherit pname version;
+
+      src = "${vsix}/${pname}.zip";
+
+      vscodeExtUniqueId = "${publisher}.${pname}";
+      vscodeExtPublisher = publisher;
+      vscodeExtName = pname;
+    };
+in {
+  flake.commonModules.codium-ai-code = package;
+}