From 99fb7b8a6273fbfc5007113a35aec858c995dd91 Mon Sep 17 00:00:00 2001
From: Leyla Becker <git@jan-leila.com>
Date: Sat, 26 Jul 2025 12:50:21 -0500
Subject: [PATCH] started to move extensions into configurable options

---
 .../leyla/packages/vscode/default.nix         | 26 ++++++----------
 .../home-manager-modules/programs/default.nix |  1 +
 .../programs/vscode/aiCode.nix                | 31 +++++++++++++++++++
 .../programs/vscode/atomKeybindings.nix       | 27 ++++++++++++++++
 .../programs/vscode/default.nix               |  7 +++++
 .../programs/vscode/oneDark.nix               | 30 ++++++++++++++++++
 6 files changed, 106 insertions(+), 16 deletions(-)
 create mode 100644 modules/home-manager-modules/programs/vscode/aiCode.nix
 create mode 100644 modules/home-manager-modules/programs/vscode/atomKeybindings.nix
 create mode 100644 modules/home-manager-modules/programs/vscode/default.nix
 create mode 100644 modules/home-manager-modules/programs/vscode/oneDark.nix

diff --git a/configurations/home-manager/leyla/packages/vscode/default.nix b/configurations/home-manager/leyla/packages/vscode/default.nix
index c28861f..5294ed2 100644
--- a/configurations/home-manager/leyla/packages/vscode/default.nix
+++ b/configurations/home-manager/leyla/packages/vscode/default.nix
@@ -29,7 +29,6 @@ in {
 
           userSettings = lib.mkMerge [
             {
-              "workbench.colorTheme" = "Atom One Dark";
               "javascript.updateImportsOnFileMove.enabled" = "always";
               "editor.tabSize" = 2;
               "editor.insertSpaces" = false;
@@ -45,11 +44,18 @@ in {
               };
               "alejandra.program" = "alejandra";
             })
-            (lib.mkIf ai-tooling-enabled {
-              "aiCode.ollamaHost" = "http://defiant:11434";
-            })
           ];
 
+          # TODO: move the rest of the extensions into enable options like this
+          extraExtensions = {
+            oneDark.enable = true;
+            atomKeybindings.enable = true;
+            aiCode = {
+              enable = ai-tooling-enabled;
+              ollamaHost = "http://defiant:11434";
+            };
+          };
+
           extensions = let
             extension-pkgs = pkgs.nix-vscode-extensions.forVSCodeVersion config.programs.vscode.package.version;
           in (
@@ -57,8 +63,6 @@ in {
               with extension-pkgs.open-vsx; (
                 [
                   # vs code feel extensions
-                  ms-vscode.atom-keybindings
-                  akamud.vscode-theme-onedark
                   streetsidesoftware.code-spell-checker
                   streetsidesoftware.code-spell-checker-german
                   streetsidesoftware.code-spell-checker-italian
@@ -104,16 +108,6 @@ in {
                   ])
               )
             )
-            ++ (
-              with pkgs.codium-extensions; (
-                []
-                ++ (
-                  lib.lists.optionals ai-tooling-enabled [
-                    ai-code
-                  ]
-                )
-              )
-            )
           );
         };
       };
diff --git a/modules/home-manager-modules/programs/default.nix b/modules/home-manager-modules/programs/default.nix
index ee52da2..675e77d 100644
--- a/modules/home-manager-modules/programs/default.nix
+++ b/modules/home-manager-modules/programs/default.nix
@@ -16,5 +16,6 @@
     ./bruno.nix
     ./dbeaver.nix
     ./steam.nix
+    ./vscode
   ];
 }
diff --git a/modules/home-manager-modules/programs/vscode/aiCode.nix b/modules/home-manager-modules/programs/vscode/aiCode.nix
new file mode 100644
index 0000000..cd23f92
--- /dev/null
+++ b/modules/home-manager-modules/programs/vscode/aiCode.nix
@@ -0,0 +1,31 @@
+{
+  lib,
+  pkgs,
+  ...
+}: let
+  pkgsRepository = pkgs.codium-extensions;
+in {
+  options.programs.vscode.profiles = lib.mkOption {
+    type = lib.types.attrsOf (lib.types.submodule ({config, ...}: {
+      options = {
+        extraExtensions.aiCode = {
+          enable = lib.mkEnableOption "should the ai code extension for vscode be enabled";
+          extension = lib.mkPackageOption pkgsRepository "ai-code" {};
+          ollamaHost = lib.mkOption {
+            type = lib.types.nullOr lib.types.str;
+            description = "what host should be used for ollama";
+            default = null;
+          };
+        };
+      };
+      config = lib.mkIf config.extraExtensions.aiCode.enable {
+        extensions = [
+          config.extraExtensions.aiCode.extension
+        ];
+        userSettings = {
+          "aiCode.ollamaHost" = lib.mkIf (config.extraExtensions.aiCode.ollamaHost != null) config.extraExtensions.aiCode.ollamaHost;
+        };
+      };
+    }));
+  };
+}
diff --git a/modules/home-manager-modules/programs/vscode/atomKeybindings.nix b/modules/home-manager-modules/programs/vscode/atomKeybindings.nix
new file mode 100644
index 0000000..95cd928
--- /dev/null
+++ b/modules/home-manager-modules/programs/vscode/atomKeybindings.nix
@@ -0,0 +1,27 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  pkgsRepositories = pkgs.nix-vscode-extensions.forVSCodeVersion config.programs.vscode.package.version;
+  pkgsRepository = pkgsRepositories.open-vsx;
+in {
+  options.programs.vscode.profiles = lib.mkOption {
+    type = lib.types.attrsOf (lib.types.submodule ({config, ...}: {
+      options = {
+        extraExtensions.atomKeybindings = {
+          enable = lib.mkEnableOption "should the atom keybindings extension for vscode be enabled";
+          extension = lib.mkPackageOption pkgsRepository "atom-keybindings" {
+            default = ["ms-vscode" "atom-keybindings"];
+          };
+        };
+      };
+      config = lib.mkIf config.extraExtensions.atomKeybindings.enable {
+        extensions = [
+          config.extraExtensions.atomKeybindings.extension
+        ];
+      };
+    }));
+  };
+}
diff --git a/modules/home-manager-modules/programs/vscode/default.nix b/modules/home-manager-modules/programs/vscode/default.nix
new file mode 100644
index 0000000..a5fe474
--- /dev/null
+++ b/modules/home-manager-modules/programs/vscode/default.nix
@@ -0,0 +1,7 @@
+{...}: {
+  imports = [
+    ./oneDark.nix
+    ./atomKeybindings.nix
+    ./aiCode.nix
+  ];
+}
diff --git a/modules/home-manager-modules/programs/vscode/oneDark.nix b/modules/home-manager-modules/programs/vscode/oneDark.nix
new file mode 100644
index 0000000..5ed43f4
--- /dev/null
+++ b/modules/home-manager-modules/programs/vscode/oneDark.nix
@@ -0,0 +1,30 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  pkgsRepositories = pkgs.nix-vscode-extensions.forVSCodeVersion config.programs.vscode.package.version;
+  pkgsRepository = pkgsRepositories.open-vsx;
+in {
+  options.programs.vscode.profiles = lib.mkOption {
+    type = lib.types.attrsOf (lib.types.submodule ({config, ...}: {
+      options = {
+        extraExtensions.oneDark = {
+          enable = lib.mkEnableOption "should the one dark theme for vscode be enabled";
+          extension = lib.mkPackageOption pkgsRepository "onedark" {
+            default = ["akamud" "vscode-theme-onedark"];
+          };
+        };
+      };
+      config = lib.mkIf config.extraExtensions.oneDark.enable {
+        extensions = [
+          config.extraExtensions.oneDark.extension
+        ];
+        userSettings = {
+          "workbench.colorTheme" = "Atom One Dark";
+        };
+      };
+    }));
+  };
+}