diff --git a/configurations/home-manager/leyla/default.nix b/configurations/home-manager/leyla/default.nix
index 6d759c5..eba7f7b 100644
--- a/configurations/home-manager/leyla/default.nix
+++ b/configurations/home-manager/leyla/default.nix
@@ -87,7 +87,6 @@
     # TODO: move this into a fonts module
     home.packages = with pkgs; [
       aileron
-      nerd-fonts.open-dyslexic
     ];
     fonts.fontconfig.enable = true;
   };
diff --git a/configurations/home-manager/leyla/packages/vscode/default.nix b/configurations/home-manager/leyla/packages/vscode/default.nix
index ba9e48a..9d1b6c6 100644
--- a/configurations/home-manager/leyla/packages/vscode/default.nix
+++ b/configurations/home-manager/leyla/packages/vscode/default.nix
@@ -40,6 +40,8 @@ in {
             oneDark.enable = true;
             atomKeybindings.enable = true;
             openRemoteSsh.enable = true;
+            # I don't like how the terminal feels with open dyslexic font on and lots of parts of the UI don't get set anyways
+            openDyslexicFont.enable = false;
 
             # html development
             autoRenameTag.enable = true;
diff --git a/modules/home-manager-modules/programs/vscode/default.nix b/modules/home-manager-modules/programs/vscode/default.nix
index 85f4a62..8f366fe 100644
--- a/modules/home-manager-modules/programs/vscode/default.nix
+++ b/modules/home-manager-modules/programs/vscode/default.nix
@@ -23,5 +23,6 @@
     ./vitest.nix
     ./direnv.nix
     ./conventionalCommits.nix
+    ./openDyslexicFont.nix
   ];
 }
diff --git a/modules/home-manager-modules/programs/vscode/openDyslexicFont.nix b/modules/home-manager-modules/programs/vscode/openDyslexicFont.nix
new file mode 100644
index 0000000..acfb79c
--- /dev/null
+++ b/modules/home-manager-modules/programs/vscode/openDyslexicFont.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: {
+  options.programs.vscode.profiles = lib.mkOption {
+    type = lib.types.attrsOf (lib.types.submodule ({config, ...}: {
+      options = {
+        extraExtensions.openDyslexicFont = {
+          enable = lib.mkEnableOption "should OpenDyslexic font be set as the default font for VSCode";
+          package = lib.mkPackageOption pkgs "nerd-fonts.open-dyslexic" {
+            default = ["nerd-fonts" "open-dyslexic"];
+          };
+        };
+      };
+      config = lib.mkIf config.extraExtensions.openDyslexicFont.enable {
+        userSettings = {
+          "editor.fontFamily" = "'OpenDyslexicM Nerd Font Mono', 'OpenDyslexic', monospace";
+          "editor.fontSize" = 14;
+        };
+      };
+    }));
+  };
+
+  config = let
+    enabledProfiles =
+      lib.filter (profile: profile.extraExtensions.openDyslexicFont.enable or false)
+      (lib.attrValues config.programs.vscode.profiles);
+
+    anyProfileUsesOpenDyslexicFont = enabledProfiles != [];
+
+    fontPackages = lib.unique (map (profile: profile.extraExtensions.openDyslexicFont.package) enabledProfiles);
+  in {
+    # Ensure OpenDyslexic font packages are installed when any VSCode profile uses them
+    home.packages = fontPackages;
+
+    fonts.fontconfig.enable = lib.mkIf anyProfileUsesOpenDyslexicFont true;
+
+    # Add assertion to ensure the fonts are available
+    assertions =
+      map (fontPkg: {
+        assertion = lib.elem fontPkg config.home.packages;
+        message = "OpenDyslexic font package '${fontPkg.name or "unknown"}' must be installed when using openDyslexicFont extension for VSCode.";
+      })
+      fontPackages;
+  };
+}