refactor: moved darwin, home-manager, and system configurations to dendrite pattern

modules/home-manager/programs/vscode/go.nix

@@ -0,0 +1,36 @@
+{...}: {
+  flake.homeModules.home-manager-vscode-go = {
+    lib,
+    pkgs,
+    config,
+    ...
+  }: let
+    pkgsRepositories = pkgs.nix-vscode-extensions.forVSCodeVersion config.programs.vscode.package.version;
+    pkgsRepository = pkgsRepositories.open-vsx;
+  in {
+    options.programs.vscode.profiles = lib.mkOption {
+      type = lib.types.attrsOf (lib.types.submodule ({config, ...}: {
+        options = {
+          extraExtensions.go = {
+            enable = lib.mkEnableOption "should the go extension for vscode be enabled";
+            extension = lib.mkPackageOption pkgsRepository "go" {
+              default = ["golang" "go"];
+            };
+          };
+        };
+        config = lib.mkIf config.extraExtensions.go.enable {
+          extensions = [
+            config.extraExtensions.go.extension
+          ];
+          userSettings = {
+            "go.alternateTools" = {
+              "gopls" = "gopls";
+            };
+            "go.toolsManagement.autoUpdate" = false;
+            "go.useLanguageServer" = true;
+          };
+        };
+      }));
+    };
+  };
+}